Excel: comment faire une mise en forme conditionnelle?

Bonsoir,
Quelle formule faut-il utiliser pour faire une Mise en forme conditionnelle de 2 couleurs à partir de 3 lignes, par exemple de A1 à J3):
je voudrais en une couleur les nombres qui existent dans la première ligne et la deuxième ligne (les nombres communs aux deux lignes sont coloriés).
Ensuite, une autre couleur pour les nombres qui sont dans la première ligne et aussi dans la troisième ligne.(ici aussi les nombres des 2 lignes sont coloriés, mais sans toucher à la première couleur précedente dans le cas où un nombre serait dans les 3 lignes)

merci

Bonjour,

Pour la première ligne, sélectionne celle-ci de J1 jusqu'à A1, puis pour la première condition :

(formule est) SOMMEPROD(($A$2:$J$2)=A1)>=1

Deuxième condition :
(formule est) SOMMEPROD(($A$3:$J$3)=A1)>=1

Je t'ai fais un exemple ici sous Calc (même principe sous Excel) :
http://cjoint.com/?ekvZOnPnkZ

A +

merci pour ta réponse, toutefois je voudrais colorier les 2 lignes de la même couleur:
si le 3 est en ligne 1 et 2, les 2 "3" sont coloriés.
si le 4 est en ligne 1 et 3, les 2 "4" sont coloriés d'une autre couleur
mais si un nombre est commun aux 3 lignes, c'est la 1ere couleur qui l'emporte (celle de la ligne 1-2) (donc il ne peut pas y avoir un mélange de couleur)
a+

re,
est il possible de m'écrire cette mise en forme conditionnelle sous la forme d'un code VBA, par exemple si un numéro x est dans la ligne 1 et aussi dans la ligne 2 alors l'intérieur de la cellule est d'une couleur, si un numéro y est dans la ligne 1 et dans la ligne 3, alors l'intérieur de la cellule est d'une autre couleur.
merci

Salut

"1" en A1 et B2 => A1:Rouge, B2:Rouge
"2" en B1 et C3 => B1:vert, C3:Vert
"3" zn D1, F2 et E3 =>D1:Rouge, F2:Rouge E3:Vert
Est-ce correct ?
La macro doit-elle créer la MFC, ou seulement colorer les cellules ?A+

Bonhour Gorfael, le Forum,
Merci de ta réponse, je vais être plus précis:
la plage de MFC comprend 4 lignes de 70 cellules (avec des cellules vides)à partir de A1.
La ligne de référence pour comparer est la ligne 1.
Si un numéro est commun ligne 1 et 2: une couleur sur ces 2 lignes pour ce numéro.
Si un numéro est commun ligne 1 et 3 ET si le numéro n'a pas été colorié précédemment: une autre couleur sur ces 2 lignes pour ce numéro.
Si un numéro est commun ligne 1 et 4 ET si le numéro n'a pas été colorié précédemment: une autre couleur sur ces 2 lignes pour ce numéro.
(on voit que la priorité conditionnelle est condition 1 puis condition 2 puis condition 3) donc il ne peut y avoir dans une colonne que:
rien si pas de commun
jaune-jaune (par ex) priorité 1 ligne 1 et 2
vert-vert (par ex) priorité 2 ligne 1 et 3 si pas condition 1
orange-orange (par ex) priorité 3 ligne 1 et 4 si pas conditions 1 et 2
Merci et bonne journée


jaune-

Salut
MFC de A1 :
Condition 1
Case 1 : la formule est
Case 2 : =(SOMMEPROD((A1=$A$2:$BR$2)*1)>0)*(A1<>"")
Format : fond jaune
Condition 2
Case 1 : la formule est
Case 2 : =(SOMMEPROD((A1=$A$3:$BR$3)*1)>0)*(A1<>"")
Format : fond vert
Condition 3
Case 1 : la formule est
Case 2 : =(SOMMEPROD((A1=$A$4:$BR$4)*1)>0)*(A1<>"")
Format : fond Orange

MFC de A2 :
Condition 1
Case 1 : la formule est
Case 2 : =(SOMMEPROD((A2=$A$1:$BR$1)*1)>0)*(A2<>"")
Format : fond jaune

MFC de A3 :
Condition 1
Case 1 : la formule est
Case 2 : =(SOMMEPROD((A3=$A$1:$BR$1)*1)>0)*(SOMMEPROD((A3=$A$2:$BR$2)*1)>0)*(A3<>"")
Format : fond jaune
Condition 2
Case 1 : la formule est
Case 2 : =(SOMMEPROD((A3=$A$1:$BR$1)*1)>0)*(A3<>"")
Format : fond vert

MFC de A4 :
Condition 1
Case 1 : la formule est
Case 2 :=(SOMMEPROD((A4=$A$1:$BR$1)*1)>0)*(SOMMEPROD((A4=$A$2:$BR$2)*1)>0)*(A4<>"")
Format : fond jaune
Condition 2
Case 1 : la formule est
Case 2 :=(SOMMEPROD((A4=$A$1:$BR$1)*1)>0)*(SOMMEPROD((A4=$A$3:$BR$3)*1)>0)*(A4<>"")
Format : fond vert
Condition 3
Case 1 : la formule est
Case 2 :=(SOMMEPROD((A4=$A$1:$BR$1)*1)>0)*(A4<>"")
Format : fond Orange

Format à recopier sur les cellules de la colonne 1(A) à 70(BR)
Tu fais les MFC de A1:A4 et tu utilises l'icone pinceau (recopie Format)sur B1:BR4
A+

Bonjour Gorfael et merci pour cs formules.
Je vais mettre en oeuvre ces sommprod.
Merci beaucoup et bon samedi.